FileDialog Property

Applies to

Application Object

Returns a FileDialogobject which represents a single instance of a file dialog box.

expression.FileDialog(dialogType)

expression Required. An expression that returns one of the objects in the Applies To list.

dialogType    Required MsoFileDialogType . The type of file dialog box.

MsoFileDialogType can be one of these MsoFileDialogType constants.
msoFileDialogFilePicker
msoFileDialogFolderPicker
msoFileDialogOpen Not supported in Microsoft Access.
msoFileDialogSaveAs Not supported in Microsoft Access.

Remarks

The msoFileDialogOpen and msoFileDialogSaveAs constants are not supported in Microsoft Office Access 2007.

Example

This example illustrates how to use the FileDialog object to display a dialog box that allow the user to select one or more files. The selected files are then added to a listbox named FileList.

Private Sub cmdFileDialog_Click()
   ' Requires reference to Microsoft Office 11.0 Object Library.
   Dim fDialog As Office.FileDialog
   Dim varFile As Variant
   ' Clear listbox contents.
   Me.FileList.RowSource = ""
   ' Set up the File Dialog.
   Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
   With fDialog
      ' Allow user to make multiple selections in dialog box
      .AllowMultiSelect = True
      ' Set the title of the dialog box.
      .Title = "Please select one or more files"
      ' Clear out the current filters, and add our own.
      .Filters.Clear
      .Filters.Add "Access Databases", "*.ACCDB"
      .Filters.Add "Access Projects", "*.ADP"
      .Filters.Add "All Files", "*.*"
      ' Show the dialog box. If the .Show method returns True, the
      ' user picked at least one file. If the .Show method returns
      ' False, the user clicked Cancel.
      If .Show = True Then
         'Loop through each file selected and add it to our list box.
         For Each varFile In .SelectedItems
            Me.FileList.AddItem varFile
         Next
      Else
         MsgBox "You clicked Cancel in the file dialog box."
      End If
   End With
End Sub