An array formula is a formula that can perform multiple calculations on one or more items in an array. You can think of an array as a row or column of values, or a combination of rows and columns of values. Array formulas can return either multiple results, or a single result.
Beginning with the September 2018 update for Microsoft 365, any formula that can return multiple results will automatically spill them either down, or across into neighboring cells. This change in behavior is also accompanied by several new dynamic array functions. Dynamic array formulas, whether they're using existing functions or the dynamic array functions, only need to be input into a single cell, then confirmed by pressing Enter. Earlier, legacy array formulas require first selecting the entire output range, then confirming the formula with Ctrl+Shift+Enter. They're commonly referred to as CSE formulas.
You can use array formulas to perform complex tasks, such as:
-
Quickly create sample datasets.
-
Count the number of characters contained in a range of cells.
-
Sum only numbers that meet certain conditions, such as the lowest values in a range, or numbers that fall between an upper and lower boundary.
-
Sum every Nth value in a range of values.
The following examples show you how to create multi-cell and single-cell array formulas. Where possible, we've included examples with some of the dynamic array functions, as well as existing array formulas entered as both dynamic and legacy arrays.
Download our examples
Download an example workbook with all the array formula examples in this article.
This exercise shows you how to use multi-cell and single-cell array formulas to calculate a set of sales figures. The first set of steps uses a multi-cell formula to calculate a set of subtotals. The second set uses a single-cell formula to calculate a grand total.
-
Multi-cell array formula
-
Here we're calculating Total Sales of coupes and sedans for each salesperson by entering =F10:F19*G10:G19 in cell H10.
When you press Enter, you'll see the results spill down to cells H10:H19. Notice that the spill range is highlighted with a border when you select any cell within the spill range. You might also notice that the formulas in cells H10:H19 are grayed out. They're just there for reference, so if you want to adjust the formula, you'll need to select cell H10, where the master formula lives.
-
Single-cell array formula
In cell H20 of the example workbook, type or copy and paste =SUM(F10:F19*G10:G19), and then press Enter.
In this case, Excel multiplies the values in the array (the cell range F10 through G19), and then uses the SUM function to add the totals together. The result is a grand total of $1,590,000 in sales.
This example shows how powerful this type of formula can be. For example, suppose you have 1,000 rows of data. You can sum part or all of that data by creating an array formula in a single cell instead of dragging the formula down through the 1,000 rows. Also, notice that the single-cell formula in cell H20 is completely independent of the multi-cell formula (the formula in cells H10 through H19). This is another advantage of using array formulas — flexibility. You could change the other formulas in column H without affecting the formula in H20. It can also be good practice to have independent totals like this, as it helps validate the accuracy of your results.
-
Dynamic array formulas also offer these advantages:
-
Consistency If you click any of the cells from H10 downward, you see the same formula. That consistency can help ensure greater accuracy.
-
Safety You can't overwrite a component of a multi-cell array formula. For example, click cell H11 and press Delete. Excel won't change the array's output. To change it, you need to select the top-left cell in the array, or cell H10.
-
Smaller file sizes You can often use a single array formula instead of several intermediate formulas. For example, the car sales example uses one array formula to calculate the results in column E. If you had used standard formulas such as =F10*G10, F11*G11, F12*G12, etc., you would have used 11 different formulas to calculate the same results. That's not a big deal, but what if you had thousands of rows to total? Then it can make a big difference.
-
Efficiency Array functions can be an efficient way to build complex formulas. The array formula =SUM(F10:F19*G10:G19) is the same as this: =SUM(F10*G10,F11*G11,F12*G12,F13*G13,F14*G14,F15*G15,F16*G16,F17*G17,F18*G18,F19*G19).
-
Spilling Dynamic array formulas will automatically spill into the output range. If your source data is in an Excel table, then your dynamic array formulas will automatically resize as you add or remove data.
-
#SPILL! error Dynamic arrays introduced the #SPILL! error, which indicates that the intended spill range is blocked for some reason. When you resolve the blockage, the formula will automatically spill.
-
Array constants are a component of array formulas. You create array constants by entering a list of items and then manually surrounding the list with braces ({ }), like this:
={1,2,3,4,5} or ={"January","February","March"}
If you separate the items by using commas, you create a horizontal array (a row). If you separate the items by using semicolons, you create a vertical array (a column). To create a two-dimensional array, you delimit the items in each row with commas, and delimit each row with semicolons.
The following procedures will give you some practice in creating horizontal, vertical, and two-dimensional constants. We'll show examples using the SEQUENCE function to automatically generate array constants, as well as manually entered array constants.
-
Create a horizontal constant
Use the workbook from the previous examples, or create a new workbook. Select any empty cell and enter =SEQUENCE(1,5). The SEQUENCE function builds a 1 row by 5 column array the same as ={1,2,3,4,5}. The following result is displayed:
-
Create a vertical constant
Select any blank cell with room beneath it, and enter =SEQUENCE(5), or ={1;2;3;4;5}. The following result is displayed:
-
Create a two-dimensional constant
Select any blank cell with room to the right and beneath it, and enter =SEQUENCE(3,4). You see the following result:
You can also enter: or ={1,2,3,4;5,6,7,8;9,10,11,12}, but you'll want to pay attention to where you put semi-colons versus commas.
As you can see, the SEQUENCE option offers significant advantages over manually entering your array constant values. Primarily, it saves you time, but it can also help reduce errors from manual entry. It's also easier to read, especially as the semi-colons can be hard to distinguish from the comma separators.
Here's an example that uses array constants as part of a bigger formula. In the sample workbook, go to the Constant in a formula worksheet, or create a new worksheet.
In cell D9, we entered =SEQUENCE(1,5,3,1), but you could also enter 3, 4, 5, 6, and 7 in cells A9:H9. There's nothing special about that particular number selection, we just chose something other than 1-5 for differentiation.
In cell E11, enter =SUM(D9:H9*SEQUENCE(1,5)), or =SUM(D9:H9*{1,2,3,4,5}). The formulas return 85.
The SEQUENCE function builds the equivalent of the array constant {1,2,3,4,5}. Because Excel performs operations on expressions enclosed in parentheses first, the next two elements that come into play are the cell values in D9:H9, and the multiplication operator (*). At this point, the formula multiplies the values in the stored array by the corresponding values in the constant. It's the equivalent of:
=SUM(D9*1,E9*2,F9*3,G9*4,H9*5), or =SUM(3*1,4*2,5*3,6*4,7*5)
Finally, the SUM function adds the values, and returns 85.
To avoid using the stored array and keep the operation entirely in memory, you can replace it with another array constant:
=SUM(SEQUENCE(1,5,3,1)*SEQUENCE(1,5)), or =SUM({3,4,5,6,7}*{1,2,3,4,5})
Elements that you can use in array constants
-
Array constants can contain numbers, text, logical values (such as TRUE and FALSE), and error values such as #N/A. You can use numbers in integer, decimal, and scientific formats. If you include text, you need to surround it with quotation marks ("text").
-
Array constants can't contain additional arrays, formulas, or functions. In other words, they can contain only text or numbers that are separated by commas or semicolons. Excel displays a warning message when you enter a formula such as {1,2,A1:D4} or {1,2,SUM(Q2:Z8)}. Also, numeric values can't contain percent signs, dollar signs, commas, or parentheses.
One of the best ways to use array constants is to name them. Named constants can be much easier to use, and they can hide some of the complexity of your array formulas from others. To name an array constant and use it in a formula, do the following:
Go to Formulas > Defined Names > Define Name. In the Name box, type Quarter1. In the Refers to box, enter the following constant (remember to type the braces manually):
={"January","February","March"}
The dialog box should now look like this:
Click OK, then select any row with three blank cells, and enter =Quarter1.
The following result is displayed:
If you want the results to spill vertically instead of horizontally, you can use =TRANSPOSE(Quarter1).
If you want to display a list of 12 months, like you might use when building a financial statement, you can base one off the current year with the SEQUENCE function. The neat thing about this function is that even though only the month is displaying, there is a valid date behind it that you can use in other calculations. You'll find these examples on the Named array constant and Quick sample dataset worksheets in the example workbook.
=TEXT(DATE(YEAR(TODAY()),SEQUENCE(1,12),1),"mmm")
This uses the DATE function to create a date based on the current year, SEQUENCE creates an array constant from 1 to 12 for January through December, then the TEXT function converts the display format to "mmm" (Jan, Feb, Mar, etc.). If you wanted to display the full month name, such as January, you'd use "mmmm".
When you use a named constant as an array formula, remember to enter the equal sign, as in =Quarter1, not just Quarter1. If you don't, Excel interprets the array as a string of text and your formula won't work as expected. Finally, keep in mind that you can use combinations of functions, text and numbers. It all depends on how creative you want to get.
The following examples demonstrate a few of the ways in which you can put array constants to use in array formulas. Some of the examples use the TRANSPOSE function to convert rows to columns and vice versa.
-
Multiple each item in an array
Enter =SEQUENCE(1,12)*2, or ={1,2,3,4;5,6,7,8;9,10,11,12}*2
You can also divide with (/), add with (+), and subtract with (-).
-
Square the items in an array
Enter =SEQUENCE(1,12)^2, or ={1,2,3,4;5,6,7,8;9,10,11,12}^2
-
Find the square root of squared items in an array
Enter =SQRT(SEQUENCE(1,12)^2), or =SQRT({1,2,3,4;5,6,7,8;9,10,11,12}^2)
-
Transpose a one-dimensional row
Enter =TRANSPOSE(SEQUENCE(1,5)), or =TRANSPOSE({1,2,3,4,5})
Even though you entered a horizontal array constant, the TRANSPOSE function converts the array constant into a column.
-
Transpose a one-dimensional column
Enter =TRANSPOSE(SEQUENCE(5,1)), or =TRANSPOSE({1;2;3;4;5})
Even though you entered a vertical array constant, the TRANSPOSE function converts the constant into a row.
-
Transpose a two-dimensional constant
Enter =TRANSPOSE(SEQUENCE(3,4)), or =TRANSPOSE({1,2,3,4;5,6,7,8;9,10,11,12})
The TRANSPOSE function converts each row into a series of columns.
This section provides examples of basic array formulas.
-
Create an array from existing values
The following example explains how to use array formulas to create a new array from an existing array.
Enter =SEQUENCE(3,6,10,10), or ={10,20,30,40,50,60;70,80,90,100,110,120;130,140,150,160,170,180}
Be sure to type { (opening brace) before you type 10, and } (closing brace) after you type 180, because you're creating an array of numbers.
Next, enter =D9#, or =D9:I11 in a blank cell. A 3 x 6 array of cells appears with the same values you see in D9:D11. The # sign is called the spilled range operator, and it's Excel's way of referencing the entire array range instead of having to type it out.
-
Create an array constant from existing values
You can take the results of a spilled array formula and convert that into its component parts. Select cell D9, then press F2 to switch to edit mode. Next, press F9 to convert the cell references to values, which Excel then converts into an array constant. When you press Enter, the formula, =D9#, should now be ={10,20,30;40,50,60;70,80,90}.
-
Count characters in a range of cells
The following example shows you how to count the number of characters in a range of cells. This includes spaces.
=SUM(LEN(C9:C13))
In this case, the LEN function returns the length of each text string in each of the cells in the range. The SUM function then adds those values together and displays the result (66). If you wanted to get average number of characters, you could use:
=AVERAGE(LEN(C9:C13))
-
Contents of longest cell in range C9:C13
=INDEX(C9:C13,MATCH(MAX(LEN(C9:C13)),LEN(C9:C13),0),1)
This formula works only when a data range contains a single column of cells.
Let's take a closer look at the formula, starting from the inner elements and working outward. The LEN function returns the length of each of the items in the cell range D2:D6. The MAX function calculates the largest value among those items, which corresponds to the longest text string, which is in cell D3.
Here's where things get a little complex. The MATCH function calculates the offset (the relative position) of the cell that contains the longest text string. To do that, it requires three arguments: a lookup value, a lookup array, and a match type. The MATCH function searches the lookup array for the specified lookup value. In this case, the lookup value is the longest text string:
MAX(LEN(C9:C13)
and that string resides in this array:
LEN(C9:C13)
The match type argument in this case is 0. The match type can be a 1, 0, or -1 value.
-
1 - returns the largest value that is less than or equal to the lookup val
-
0 - returns the first value exactly equal to the lookup value
-
-1 - returns the smallest value that is greater than or equal to the specified lookup value
-
If you omit a match type, Excel assumes 1.
Finally, the INDEX function takes these arguments: an array, and a row and column number within that array. The cell range C9:C13 provides the array, the MATCH function provides the cell address, and the final argument (1) specifies that the value comes from the first column in the array.
If you wanted to get the contents of the smallest text string, you would replace MAX in the above example with MIN.
-
-
Find the n smallest values in a range
This example shows how to find the three smallest values in a range of cells, where an array of sample data in cells B9:B18has been created with: =INT(RANDARRAY(10,1)*100). Note that RANDARRAY is a volatile function, so you'll get a new set of random numbers each time Excel calculates.
Enter =SMALL(B9#,SEQUENCE(D9), =SMALL(B9:B18,{1;2;3})
This formula uses an array constant to evaluate the SMALL function three times and return the smallest 3 members in the array that's contained in cells B9:B18, where 3 is a variable value in cell D9. To find more values, you can increase the value in the SEQUENCE function, or add more arguments to the constant. You can also use additional functions with this formula, such as SUM or AVERAGE. For example:
=SUM(SMALL(B9#,SEQUENCE(D9))
=AVERAGE(SMALL(B9#,SEQUENCE(D9))
-
Find the n largest values in a range
To find the largest values in a range, you can replace the SMALL function with the LARGE function. In addition, the following example uses the ROW and INDIRECT functions.
Enter =LARGE(B9#,ROW(INDIRECT("1:3"))), or =LARGE(B9:B18,ROW(INDIRECT("1:3")))
At this point, it may help to know a bit about the ROW and INDIRECT functions. You can use the ROW function to create an array of consecutive integers. For example, select an empty and enter:
=ROW(1:10)
The formula creates a column of 10 consecutive integers. To see a potential problem, insert a row above the range that contains the array formula (that is, above row 1). Excel adjusts the row references, and the formula now generates integers from 2 to 11. To fix that problem, you add the INDIRECT function to the formula:
=ROW(INDIRECT("1:10"))
The INDIRECT function uses text strings as its arguments (which is why the range 1:10 is surrounded by quotation marks). Excel does not adjust text values when you insert rows or otherwise move the array formula. As a result, the ROW function always generates the array of integers that you want. You could just as easily use SEQUENCE:
=SEQUENCE(10)
Let's examine the formula that you used earlier — =LARGE(B9#,ROW(INDIRECT("1:3"))) — starting from the inner parentheses and working outward: The INDIRECT function returns a set of text values, in this case the values 1 through 3. The ROW function in turn generates a three-cell column array. The LARGE function uses the values in the cell range B9:B18, and it is evaluated three times, once for each reference returned by the ROW function. If you want to find more values, you add a greater cell range to the INDIRECT function. Finally, as with the SMALL examples, you can use this formula with other functions, such as SUM and AVERAGE.
-
Sum a range that contains error values
The SUM function in Excel does not work when you try to sum a range that contains an error value, such as #VALUE! or #N/A. This example shows you how to sum the values in a range named Data that contains errors:
-
=SUM(IF(ISERROR(Data),"",Data))
The formula creates a new array that contains the original values minus any error values. Starting from the inner functions and working outward, the ISERROR function searches the cell range (Data) for errors. The IF function returns a specific value if a condition you specify evaluates to TRUE and another value if it evaluates to FALSE. In this case, it returns empty strings ("") for all error values because they evaluate to TRUE, and it returns the remaining values from the range (Data) because they evaluate to FALSE, meaning that they don't contain error values. The SUM function then calculates the total for the filtered array.
-
Count the number of error values in a range
This example is like the previous formula, but it returns the number of error values in a range named Data instead of filtering them out:
=SUM(IF(ISERROR(Data),1,0))
This formula creates an array that contains the value 1 for the cells that contain errors and the value 0 for the cells that don't contain errors. You can simplify the formula and achieve the same result by removing the third argument for the IF function, like this:
=SUM(IF(ISERROR(Data),1))
If you don't specify the argument, the IF function returns FALSE if a cell does not contain an error value. You can simplify the formula even more:
=SUM(IF(ISERROR(Data)*1))
This version works because TRUE*1=1 and FALSE*1=0.
You might need to sum values based on conditions.
For example, this array formula sums just the positive integers in a range named Sales, which represents cells E9:E24 in the example above:
=SUM(IF(Sales>0,Sales))
The IF function creates an array of positive and false values. The SUM function essentially ignores the false values because 0+0=0. The cell range that you use in this formula can consist of any number of rows and columns.
You can also sum values that meet more than one condition. For example, this array formula calculates values greater than 0 AND less than 2500:
=SUM((Sales>0)*(Sales<2500)*(Sales))
Keep in mind that this formula returns an error if the range contains one or more non-numeric cells.
You can also create array formulas that use a type of OR condition. For example, you can sum values that are greater than 0 OR less than 2500:
=SUM(IF((Sales>0)+(Sales<2500),Sales))
You can't use the AND and OR functions in array formulas directly because those functions return a single result, either TRUE or FALSE, and array functions require arrays of results. You can work around the problem by using the logic shown in the previous formula. In other words, you perform math operations, such as addition or multiplication on values that meet the OR or AND condition.
This example shows you how to remove zeros from a range when you need to average the values in that range. The formula uses a data range named Sales:
=AVERAGE(IF(Sales<>0,Sales))
The IF function creates an array of values that do not equal 0 and then passes those values to the AVERAGE function.
This array formula compares the values in two ranges of cells named MyData and YourData and returns the number of differences between the two. If the contents of the two ranges are identical, the formula returns 0. To use this formula, the cell ranges need to be the same size and of the same dimension. For example, if MyData is a range of 3 rows by 5 columns, YourData must also be 3 rows by 5 columns:
=SUM(IF(MyData=YourData,0,1))
The formula creates a new array of the same size as the ranges that you are comparing. The IF function fills the array with the value 0 and the value 1 (0 for mismatches and 1 for identical cells). The SUM function then returns the sum of the values in the array.
You can simplify the formula like this:
=SUM(1*(MyData<>YourData))
Like the formula that counts error values in a range, this formula works because TRUE*1=1, and FALSE*1=0.
This array formula returns the row number of the maximum value in a single-column range named Data:
=MIN(IF(Data=MAX(Data),ROW(Data),""))
The IF function creates a new array that corresponds to the range named Data. If a corresponding cell contains the maximum value in the range, the array contains the row number. Otherwise, the array contains an empty string (""). The MIN function uses the new array as its second argument and returns the smallest value, which corresponds to the row number of the maximum value in Data. If the range named Data contains identical maximum values, the formula returns the row of the first value.
If you want to return the actual cell address of a maximum value, use this formula:
=ADDRESS(MIN(IF(Data=MAX(Data),ROW(Data),"")),COLUMN(Data))
You'll find similar examples in the sample workbook on the Differences between datasets worksheet.
This exercise shows you how to use multi-cell and single-cell array formulas to calculate a set of sales figures. The first set of steps uses a multi-cell formula to calculate a set of subtotals. The second set uses a single-cell formula to calculate a grand total.
-
Multi-cell array formula
Copy the entire table below and paste it into cell A1 in a blank worksheet.
| Sales Person | Car Type | Number Sold | Unit Price | Total Sales |
|---|---|---|---|---|
| Barnhill | Sedan | 5 | 33000 | |
| Coupe | 4 | 37000 | ||
| Ingle | Sedan | 6 | 24000 | |
| Coupe | 8 | 21000 | ||
| Jordan | Sedan | 3 | 29000 | |
| Coupe | 1 | 31000 | ||
| Pica | Sedan | 9 | 24000 | |
| Coupe | 5 | 37000 | ||
| Sanchez | Sedan | 6 | 33000 | |
| Coupe | 8 | 31000 | ||
| Formula (Grand Total) | Grand Total | |||
| '=SUM(C2:C11*D2:D11) | =SUM(C2:C11*D2:D11) |
-
To see Total Sales of coupes and sedans for each salesperson, select cells E2:E11, enter the formula =C2:C11*D2:D11, and then press Ctrl+Shift+Enter.
-
To see the Grand Total of all sales, select cell F11, enter the formula =SUM(C2:C11*D2:D11), and then press Ctrl+Shift+Enter.
When you press Ctrl+Shift+Enter, Excel surrounds the formula with braces ({ }) and inserts an instance of the formula in each cell of the selected range. This happens very quickly, so what you see in column E is the total sales amount for each car type for each salesperson. If you select E2, then select E3, E4, and so on, you'll see that the same formula is shown: {=C2:C11*D2:D11}.
-
Create a single-cell array formula
In cell D13 of the workbook, type the following formula, and then press Ctrl+Shift+Enter:
=SUM(C2:C11*D2:D11)
In this case, Excel multiplies the values in the array (the cell range C2 through D11) and then uses the SUM function to add the totals together. The result is a grand total of $1,590,000 in sales. This example shows how powerful this type of formula can be. For example, suppose you have 1,000 rows of data. You can sum part or all of that data by creating an array formula in a single cell instead of dragging the formula down through the 1,000 rows.
Also, notice that the single-cell formula in cell D13 is completely independent of the multi-cell formula (the formula in cells E2 through E11). This is another advantage of using array formulas — flexibility. You could change the formulas in column E or delete that column altogether, without affecting the formula in D13.
Array formulas also offer these advantages:
-
Consistency If you click any of the cells from E2 downward, you see the same formula. That consistency can help ensure greater accuracy.
-
Safety You cannot overwrite a component of a multi-cell array formula. For example, click cell E3 and press Delete. You have to either select the entire range of cells (E2 through E11) and change the formula for the entire array, or leave the array as is. As an added safety measure, you have to press Ctrl+Shift+Enter to confirm any change to the formula.
-
Smaller file sizes You can often use a single array formula instead of several intermediate formulas. For example, the workbook uses one array formula to calculate the results in column E. If you had used standard formulas (such as =C2*D2, C3*D3, C4*D4…), you would have used 11 different formulas to calculate the same results.
In general, array formulas use standard formula syntax. They all begin with an equal (=) sign, and you can use most of the built-in Excel functions in your array formulas. The key difference is that when using an array formula, you press Ctrl+Shift+Enter to enter your formula. When you do this, Excel surrounds your array formula with braces — if you type the braces manually, your formula will be converted to a text string, and it won't work.
Array functions can be an efficient way to build complex formulas. The array formula =SUM(C2:C11*D2:D11) is the same as this: =SUM(C2*D2,C3*D3,C4*D4,C5*D5,C6*D6,C7*D7,C8*D8,C9*D9,C10*D10,C11*D11).
Important: Press Ctrl+Shift+Enter whenever you need to enter an array formula. This applies to both single-cell and multi-cell formulas.
Whenever you work with multi-cell formulas, also remember:
-
Select the range of cells to hold your results before you enter the formula. You did this when you created the multi-cell array formula when you selected cells E2 through E11.
-
You can't change the contents of an individual cell in an array formula. To try this, select cell E3 in the workbook and press Delete. Excel displays a message that tells you that you can't change part of an array.
-
You can move or delete an entire array formula, but you can't move or delete part of it. In other words, to shrink an array formula, you first delete the existing formula and then start over.
-
To delete an array formula, select the entire formula range (for example, E2:E11), then press Delete.
-
You can't insert blank cells into, or delete cells from a multi-cell array formula.
At times, you may need to expand an array formula. Select the first cell in existing array range, and continue until you've selected the entire range that you want to extend the formula to. Press F2 to edit the formula, then press CTRL+SHIFT+ENTER to confirm the formula once you've adjusted the formula range. The key is to select the entire range, starting with the top-left cell in the array. The top-left cell is the one that gets edited.
Array formulas are great, but they can have some disadvantages:
-
You may occasionally forget to press Ctrl+Shift+Enter. It can happen to even the most experienced Excel users. Remember to press this key combination whenever you enter or edit an array formula.
-
Other users of your workbook might not understand your formulas. In practice, array formulas are generally not explained in a worksheet. Therefore, if other people need to modify your workbooks, you should either avoid array formulas or make sure those people know about any array formulas and understand how to change them, if they need to.
-
Depending on the processing speed and memory of your computer, large array formulas can slow down calculations.
Array constants are a component of array formulas. You create array constants by entering a list of items and then manually surrounding the list with braces ({ }), like this:
={1,2,3,4,5}
By now, you know you need to press Ctrl+Shift+Enter when you create array formulas. Because array constants are a component of array formulas, you surround the constants with braces by manually typing them. You then use Ctrl+Shift+Enter to enter the entire formula.
If you separate the items by using commas, you create a horizontal array (a row). If you separate the items by using semicolons, you create a vertical array (a column). To create a two-dimensional array, you delimit the items in each row by using commas and delimit each row by using semicolons.
Here's an array in a single row: {1,2,3,4}. Here's an array in a single column: {1;2;3;4}. And here's an array of two rows and four columns: {1,2,3,4;5,6,7,8}. In the two row array, the first row is 1, 2, 3, and 4, and the second row is 5, 6, 7, and 8. A single semicolon separates the two rows, between 4 and 5.
As with array formulas, you can use array constants with most of the built-in functions that Excel provides. The following sections explain how to create each kind of constant and how to use these constants with functions in Excel.
The following procedures will give you some practice in creating horizontal, vertical, and two-dimensional constants.
Create a horizontal constant
-
In a blank worksheet, select cells A1 through E1.
-
In the formula bar, enter the following formula, and then press Ctrl+Shift+Enter:
={1,2,3,4,5}
In this case, you should type the opening and closing braces ({ }), and Excel will add the second set for you.
The following result is displayed.
Create a vertical constant
-
In your workbook, select a column of five cells.
-
In the formula bar, enter the following formula, and then press Ctrl+Shift+Enter:
={1;2;3;4;5}
The following result is displayed.
Create a two-dimensional constant
-
In your workbook, select a block of cells four columns wide by three rows high.
-
In the formula bar, enter the following formula, and then press Ctrl+Shift+Enter:
={1,2,3,4;5,6,7,8;9,10,11,12}
You see the following result:
Use constants in formulas
Here is a simple example that uses constants:
-
In the sample workbook, create a new worksheet.
-
In cell A1, type 3, and then type 4 in B1, 5 in C1, 6 in D1, and 7 in E1.
-
In cell A3, type the following formula, and then press Ctrl+Shift+Enter:
=SUM(A1:E1*{1,2,3,4,5})
Notice that Excel surrounds the constant with another set of braces, because you entered it as an array formula.
The value 85 appears in cell A3.
The next section explains how the formula works.
The formula you just used contains several parts.
1. Function
2. Stored array
3. Operator
4. Array constant
The last element inside the parentheses is the array constant: {1,2,3,4,5}. Remember that Excel does not surround array constants with braces; you actually type them. Also remember that after you add a constant to an array formula, you press Ctrl+Shift+Enter to enter the formula.
Because Excel performs operations on expressions enclosed in parentheses first, the next two elements that come into play are the values stored in the workbook (A1:E1) and the operator. At this point, the formula multiplies the values in the stored array by the corresponding values in the constant. It's the equivalent of:
=SUM(A1*1,B1*2,C1*3,D1*4,E1*5)
Finally, the SUM function adds the values, and the sum 85 appears in cell A3.
To avoid using the stored array and to just keep the operation entirely in memory, replace the stored array with another array constant:
=SUM({3,4,5,6,7}*{1,2,3,4,5})
To try this, copy the function, select a blank cell in your workbook, paste the formula into the formula bar, and then press Ctrl+Shift+Enter. You'll see the same result as you did in the earlier exercise that used the array formula:
=SUM(A1:E1*{1,2,3,4,5})
Array constants can contain numbers, text, logical values (such as TRUE and FALSE), and error values ( such as #N/A). You can use numbers in the integer, decimal, and scientific formats. If you include text, you need to surround the text with quotation marks (").
Array constants can't contain additional arrays, formulas, or functions. In other words, they can contain only text or numbers that are separated by commas or semicolons. Excel displays a warning message when you enter a formula such as {1,2,A1:D4} or {1,2,SUM(Q2:Z8)}. Also, numeric values can't contain percent signs, dollar signs, commas, or parentheses.
One of the best way to use array constants is to name them. Named constants can be much easier to use, and they can hide some of the complexity of your array formulas from others. To name an array constant and use it in a formula, do the following:
-
On the Formulas tab, in the Defined Names group, click Define Name.
The Define Name dialog box appears. -
In the Name box, type Quarter1.
-
In the Refers to box, enter the following constant (remember to type the braces manually):
={"January","February","March"}
The contents of the dialog box now looks like this:
-
Click OK, and then select a row of three blank cells.
-
Type the following formula, and then press Ctrl+Shift+Enter.
=Quarter1
The following result is displayed.
When you use a named constant as an array formula, remember to enter the equal sign. If you don't, Excel interprets the array as a string of text and your formula won't work as expected. Finally, keep in mind that you can use combinations of text and numbers.
Look for the following problems when your array constants don't work:
-
Some elements might not be separated with the proper character. If you omit a comma or semicolon, or if you put one in the wrong place, the array constant might not be created correctly, or you might see a warning message.
-
You might have selected a range of cells that doesn't match the number of elements in your constant. For example, if you select a column of six cells for use with a five-cell constant, the #N/A error value appears in the empty cell. Conversely, if you select too few cells, Excel omits the values that don't have a corresponding cell.
The following examples demonstrate a few of the ways in which you can put array constants to use in array formulas. Some of the examples use the TRANSPOSE function to convert rows to columns and vice versa.
Multiply each item in an array
-
Create a new worksheet, and then select a block of empty cells four columns wide by three rows high.
-
Type the following formula, and then press Ctrl+Shift+Enter:
={1,2,3,4;5,6,7,8;9,10,11,12}*2
Square the items in an array
-
Select a block of empty cells four columns wide by three rows high.
-
Type the following array formula, and then press Ctrl+Shift+Enter:
={1,2,3,4;5,6,7,8;9,10,11,12}*{1,2,3,4;5,6,7,8;9,10,11,12}
Alternatively, enter this array formula, which uses the caret operator (^):
={1,2,3,4;5,6,7,8;9,10,11,12}^2
Transpose a one-dimensional row
-
Select a column of five blank cells.
-
Type the following formula, and then press Ctrl+Shift+Enter:
=TRANSPOSE({1,2,3,4,5})
Even though you entered a horizontal array constant, the TRANSPOSE function converts the array constant into a column.
Transpose a one-dimensional column
-
Select a row of five blank cells.
-
Enter the following formula, and then press Ctrl+Shift+Enter:
=TRANSPOSE({1;2;3;4;5})
Even though you entered a vertical array constant, the TRANSPOSE function converts the constant into a row.
Transpose a two-dimensional constant
-
Select a block of cells three columns wide by four rows high.
-
Enter the following constant, and then press Ctrl+Shift+Enter:
=TRANSPOSE({1,2,3,4;5,6,7,8;9,10,11,12})
The TRANSPOSE function converts each row into a series of columns.
This section provides examples of basic array formulas.
Create arrays and array constants from existing values
The following example explains how to use array formulas to create links between ranges of cells in different worksheets. It also shows you how to create an array constant from the same set of values.
Create an array from existing values
-
On a worksheet in Excel, select cells C8:E10, and enter this formula:
={10,20,30;40,50,60;70,80,90}
Be sure to type { (opening brace) before you type 10, and } (closing brace) after you type 90, because you're creating an array of numbers.
-
Press Ctrl+Shift+Enter, which enters this array of numbers in the cell range C8:E10 by using an array formula. On your worksheet, C8 through E10 should look like this:
10
20
30
40
50
60
70
80
90
-
Select the cell range C1 through E3.
-
Enter the following formula in the formula bar, and then press Ctrl+Shift+Enter:
=C8:E10
A 3x3 array of cells appears in cells C1 through E3 with the same values you see in C8 through E10.
Create an array constant from existing values
-
With cells C1:C3 selected, press F2 to switch to edit mode.
-
Press F9 to convert the cell references to values. Excel converts the values into an array constant. The formula should now be ={10,20,30;40,50,60;70,80,90}.
-
Press Ctrl+Shift+Enter to enter the array constant as an array formula.
Count characters in a range of cells
The following example shows you how to count the number of characters, including spaces, in a range of cells.
-
Copy this entire table and paste into a worksheet in cell A1.
Data
This is a
bunch of cells that
come together
to form a
single sentence.
Total characters in A2:A6
=SUM(LEN(A2:A6))
Contents of longest cell (A3)
=INDEX(A2:A6,MATCH(MAX(LEN(A2:A6)),LEN(A2:A6),0),1)
-
Select cell A8, and then press Ctrl+Shift+Enter to see the total number of characters in cells A2:A6 (66).
-
Select cell A10, and then press Ctrl+Shift+Enter to see the contents of the longest of cells A2:A6 (cell A3).
The following formula is used in cell A8 counts the total number of characters (66) in cells A2 through A6.
=SUM(LEN(A2:A6))
In this case, the LEN function returns the length of each text string in each of the cells in the range. The SUM function then adds those values together and displays the result (66).
Find the n smallest values in a range
This example shows how to find the three smallest values in a range of cells.
-
Enter some random numbers in cells A1:A11.
-
Select cells C1 through C3. This set of cells will hold the results returned by the array formula.
-
Enter the following formula, and then press Ctrl+Shift+Enter:
=SMALL(A1:A11,{1;2;3})
This formula uses an array constant to evaluate the SMALL function three times and return the smallest (1), second smallest (2), and third smallest (3) members in the array that is contained in cells A1:A10 To find more values, you add more arguments to the constant. You can also use additional functions with this formula, such as SUM or AVERAGE. For example:
=SUM(SMALL(A1:A10,{1,2,3})
=AVERAGE(SMALL(A1:A10,{1,2,3})
Find the n largest values in a range
To find the largest values in a range, you can replace the SMALL function with the LARGE function. In addition, the following example uses the ROW and INDIRECT functions.
-
Select cells D1 through D3.
-
In the formula bar, enter this formula, and then press Ctrl+Shift+Enter:
=LARGE(A1:A10,ROW(INDIRECT("1:3")))
At this point, it may help to know a bit about the ROW and INDIRECT functions. You can use the ROW function to create an array of consecutive integers. For example, select an empty column of 10 cells in your practice workbook, enter this array formula, and then press Ctrl+Shift+Enter:
=ROW(1:10)
The formula creates a column of 10 consecutive integers. To see a potential problem, insert a row above the range that contains the array formula (that is, above row 1). Excel adjusts the row references, and the formula generates integers from 2 to 11. To fix that problem, you add the INDIRECT function to the formula:
=ROW(INDIRECT("1:10"))
The INDIRECT function uses text strings as its arguments (which is why the range 1:10 is surrounded by double quotation marks). Excel does not adjust text values when you insert rows or otherwise move the array formula. As a result, the ROW function always generates the array of integers that you want.
Let's take a look at the formula that you used earlier — =LARGE(A5:A14,ROW(INDIRECT("1:3"))) — starting from the inner parentheses and working outward: The INDIRECT function returns a set of text values, in this case the values 1 through 3. The ROW function in turn generates a three-cell columnar array. The LARGE function uses the values in the cell range A5:A14, and it is evaluated three times, once for each reference returned by the ROW function. The values 3200, 2700, and 2000 are returned to the three-cell columnar array. If you want to find more values, you add a greater cell range to the INDIRECT function.
As with earlier examples, you can use this formula with other functions, such as SUM and AVERAGE.
Find the longest text string in a range of cells
Go back to the earlier text string example, enter the following formula in an empty cell, and press Ctrl+Shift+Enter:
=INDEX(A2:A6,MATCH(MAX(LEN(A2:A6)),LEN(A2:A6),0),1)
The text "bunch of cells that" appears.
Let's take a closer look at the formula, starting from the inner elements and working outward. The LEN function returns the length of each of the items in the cell range A2:A6. The MAX function calculates the largest value among those items, which corresponds to the longest text string, which is in cell A3.
Here's where things get a little complex. The MATCH function calculates the offset (the relative position) of the cell that contains the longest text string. To do that, it requires three arguments: a lookup value, a lookup array, and a match type. The MATCH function searches the lookup array for the specified lookup value. In this case, the lookup value is the longest text string:
(MAX(LEN(A2:A6))
and that string resides in this array:
LEN(A2:A6)
The match type argument is 0. The match type can consist of a 1, 0, or -1 value. If you specify 1, MATCH returns the largest value that is less than or equal to the lookup value. If you specify 0, MATCH returns the first value exactly equal to the lookup value. If you specify -1, MATCH finds the smallest value that is greater than or equal to the specified lookup value. If you omit a match type, Excel assumes 1.
Finally, the INDEX function takes these arguments: an array, and a row and column number within that array. The cell range A2:A6 provides the array, the MATCH function provides the cell address, and the final argument (1) specifies that the value comes from the first column in the array.
This section provides examples of advanced array formulas.
Sum a range that contains error values
The SUM function in Excel does not work when you try to sum a range that contains an error value, such as #N/A. This example shows you how to sum the values in a range named Data that contains errors.
=SUM(IF(ISERROR(Data),"",Data))
The formula creates a new array that contains the original values minus any error values. Starting from the inner functions and working outward, the ISERROR function searches the cell range (Data) for errors. The IF function returns a specific value if a condition you specify evaluates to TRUE and another value if it evaluates to FALSE. In this case, it returns empty strings ("") for all error values because they evaluate to TRUE, and it returns the remaining values from the range (Data) because they evaluate to FALSE, meaning that they don't contain error values. The SUM function then calculates the total for the filtered array.
Count the number of error values in a range
This example is similar to the previous formula, but it returns the number of error values in a range named Data instead of filtering them out:
=SUM(IF(ISERROR(Data),1,0))
This formula creates an array that contains the value 1 for the cells that contain errors and the value 0 for the cells that don't contain errors. You can simplify the formula and achieve the same result by removing the third argument for the IF function, like this:
=SUM(IF(ISERROR(Data),1))
If you don't specify the argument, the IF function returns FALSE if a cell does not contain an error value. You can simplify the formula even more:
=SUM(IF(ISERROR(Data)*1))
This version works because TRUE*1=1 and FALSE*1=0.
Sum values based on conditions
You might need to sum values based on conditions. For example, this array formula sums just the positive integers in a range named Sales:
=SUM(IF(Sales>0,Sales))
The IF function creates an array of positive values and false values. The SUM function essentially ignores the false values because 0+0=0. The cell range that you use in this formula can consist of any number of rows and columns.
You can also sum values that meet more than one condition. For example, this array formula calculates values greater than 0 and less than or equal to 5:
=SUM((Sales>0)*(Sales<=5)*(Sales))
Keep in mind that this formula returns an error if the range contains one or more non-numeric cells.
You can also create array formulas that use a type of OR condition. For example, you can sum values that are less than 5 and greater than 15:
=SUM(IF((Sales<5)+(Sales>15),Sales))
The IF function finds all values smaller than 5 and greater than 15 and then passes those values to the SUM function.
You can't use the AND and OR functions in array formulas directly because those functions return a single result, either TRUE or FALSE, and array functions require arrays of results. You can work around the problem by using the logic shown in the previous formula. In other words, you perform math operations, such as addition or multiplication, on values that meet the OR or AND condition.
Compute an average that excludes zeros
This example shows you how to remove zeros from a range when you need to average the values in that range. The formula uses a data range named Sales:
=AVERAGE(IF(Sales<>0,Sales))
The IF function creates an array of values that do not equal 0 and then passes those values to the AVERAGE function.
Count the number of differences between two ranges of cells
This array formula compares the values in two ranges of cells named MyData and YourData and returns the number of differences between the two. If the contents of the two ranges are identical, the formula returns 0. To use this formula, the cell ranges need to be the same size and of the same dimension (for example, if MyData is a range of 3 rows by 5 columns, YourData must also be 3 rows by 5 columns):
=SUM(IF(MyData=YourData,0,1))
The formula creates a new array of the same size as the ranges that you are comparing. The IF function fills the array with the value 0 and the value 1 (0 for mismatches and 1 for identical cells). The SUM function then returns the sum of the values in the array.
You can simplify the formula like this:
=SUM(1*(MyData<>YourData))
Like the formula that counts error values in a range, this formula works because TRUE*1=1, and FALSE*1=0.
Find the location of the maximum value in a range
This array formula returns the row number of the maximum value in a single-column range named Data:
=MIN(IF(Data=MAX(Data),ROW(Data),""))
The IF function creates a new array that corresponds to the range named Data. If a corresponding cell contains the maximum value in the range, the array contains the row number. Otherwise, the array contains an empty string (""). The MIN function uses the new array as its second argument and returns the smallest value, which corresponds to the row number of the maximum value in Data. If the range named Data contains identical maximum values, the formula returns the row of the first value.
If you want to return the actual cell address of a maximum value, use this formula:
=ADDRESS(MIN(IF(Data=MAX(Data),ROW(Data),"")),COLUMN(Data))
Acknowledgement
Parts of this article were based on a series of Excel Power User columns written by Colin Wilcox, and adapted from chapters 14 and 15 of Excel 2002 Formulas, a book written by John Walkenbach, a former Excel MVP.
Need more help?
You can always ask an expert in the Excel Tech Community or get support in the Answers community.
See Also
Dynamic arrays and spilled array behavior
Dynamic array formulas vs. legacy CSE array formulas
No comments:
Post a Comment